Função SE (IF) no Google Planilhas - do básico ao avançado

PUBLICADO POR AYLTON INACIO
Tutoriais e Artigos > Google Tools

Se você usa o Google Planilhas de forma avançada ou intermediária, com certeza já precisou trabalhar com a função SE para testes condicionais. No Google Planilhas as funções são em inglês, então temos a IF para esse propósito com uma sintaxe bem parecida com a do Excel.

▶ Se preferir, acesse "Como usar a função SE no Google Planilhas: básico e avançado" no YouTube.

A função SE no Google Planilhas (IF) tem a seguinte sintaxe:

IF(expressao_logica; valor_se_verdadeiro; valor_se_falso)

O objetivo é trocar expressao_logica por um teste condicional, ou seja, que retorna verdadeiro ou falso. Se o resultado for verdadeiro, o bloco valor_se_verdadeiro será executado, senão o bloco valor_se_falso.

Por exemplo, para verificar se a nota da Maria que está na célula B2 é maior ou igual a 7, e retornar o texto "Aprovado" como resultado, a seguinte fórmula pode ser utilizada:

IF(B2 >= 7; "Aprovado"; "Reprovado")

Este é o exemplo mais simples da função SE no Google Planilhas. Importante destacar que o uso pode ir muito além disso. Por exemplo, é possível trocar "Aprovado" por cálculos matemáticos e outras funções do Planilhas, até mesmo por uma outra função IF para fazer diversos testes aninhados.

Você também pode trocar o B2 >= 7 por uma função AND ou OR, que fazem diversos testes lógicos que dependem ou não uns dos outros na análise para então retornar verdadeiro ou falso.

Função SE avançada na prática!

Nada melhor que um exemplo prático para aplicar e entender como a função SE pode ser aplicada em situações mais avançadas.

O objetivo é calcular a Nota Final com uma média simples das 4 notas e reduzir pontos de acordo com as seguintes regras:

Regra 1 - Para cada advertência, tirar 0,1 se a idade for menor ou igual a 20. Se a idade for maior ou igual a 30, retirar 0,2, senão retirar 0,15.

Regra 2 - Para cada falta, tirar 0,05 se não tiver advertências. Se tiver, tirar 0,1.

Regra 3 - Se a idade do aluno for maior ou igual a 30 E tiver faltas E tiver advertências, retirar 0,5.

O primeiro passo é fazer a média normal na coluna I (célula I2) usando a seguinte fórmula:

=AVERAGE(E2:H2)

O nosso objetivo é fazer apenas uma fórmula para a coluna J com a Nota Final, mas é importante estudar as várias partes dela separadamente, então vamos deixar ela em branco por enquanto.

Coloque na coluna K (célula K2) a seguinte fórmula para aplicar a regra 1:

=if(B2<=20;C2*0,1;if(B2>=30;C2*0,2;C2*0,15))

Coloque na coluna L (célula L2) a seguinte fórmula para aplicar a regra 2:

=if(C2=0;D2*0,05;D2*0,1)

Aplique as fórmulas para todos os alunos, respeitando as células de cada um. No final você terá nas colunas K e L as pontuações que devem ser retiradas da média com base nas regras 1 e 2.

Coloque na coluna M (célula M2) a seguinte fórmula para aplicar a regra 3:

=if(AND(B2>=30;C2>0;D2>0);0,5;0)

Na fórmula da regra 3 foi utilizada a função AND em conjunto com a IF, no bloco do teste lógico. Ela faz vários testes lógicos e todos devem ser verdadeiros para o resultado final também ser verdadeiro.

Com as fórmulas criadas até o momento, temos todos os valores que devem ser reduzidos da média. Não queremos deixar esses valores visíveis, mas sim juntar tudo em apenas uma fórmula na coluna J.

Coloque na coluna J (célula J2) a seguinte fórmula para criar a Nota Final:

=I2-if(B2<=20;C2*0,1;if(B2>=30;C2*0,2;C2*0,15))-if(C2=0;D2*0,05;D2*0,1)-if(AND(B2>=30;C2>0;D2>0);0,5;0)

Na coluna I temos a média, então foi feito I2 (nossa média) MENOS a fórmula da regra 1 MENOS a fórmula da regra 2 MENOS a fórmula da regra 3, chegando assim na Nota Final.

Agora é com você criar outras planilhas usando outras soluções com a função SE do Google Planilhas, em conjunto com outras fórmulas e funções.